ESP8266 Community Forum

- Thu Mar 03, 2016 3:53 pm #42358

I've had 8xDS18B20s each with 3m wire all working fine at the same time on the same GPIO with the internal pull-up resistor.

You're lucky and probably don't have lot of ESR intereferences around.
The Dallas specs are really mentioning 4K7 as the standard way to pull it up.

- Thu Mar 03, 2016 4:11 pm #42359 Hi!

Thanks for your answers! Yes, I'm using a 4.7k pull up.

I don't receive 85 °C exactly and constantly, but changing values over time. I can also see the values in- and decrease when they should.

I'll post the code in a minute...

- Thu Mar 03, 2016 4:13 pm #42360 Here comes the code:

Code: Select all#include <OneWire.h>

// OneWire DS18S20, DS18B20, DS1822 Temperature Example
//
// http://www.pjrc.com/teensy/td_libs_OneWire.html
//
// The DallasTemperature library can do all this work for you!
// http://milesburton.com/Dallas_Temperature_Control_Library

OneWire  ds(2);  // on pin 10 (a 4.7K resistor is necessary)

void setup(void) {
  Serial.begin(115200);
}

void loop(void) {
  byte i;
  byte present = 0;
  byte type_s;
  byte data[12];
  byte addr[8];
  float celsius, fahrenheit;
 
  if ( !ds.search(addr)) {
    Serial.println("No more addresses.");
    Serial.println();
    ds.reset_search();
    delay(250);
    return;
  }
 
  Serial.print("ROM =");
  for( i = 0; i < 8; i++) {
    Serial.write(' ');
    Serial.print(addr[i], HEX);
  }

  if (OneWire::crc8(addr, 7) != addr[7]) {
      Serial.println("CRC is not valid!");
      return;
  }
  Serial.println();
 
  // the first ROM byte indicates which chip
  switch (addr[0]) {
    case 0x10:
      Serial.println("  Chip = DS18S20");  // or old DS1820
      type_s = 1;
      break;
    case 0x28:
      Serial.println("  Chip = DS18B20");
      type_s = 0;
      break;
    case 0x22:
      Serial.println("  Chip = DS1822");
      type_s = 0;
      break;
    default:
      Serial.println("Device is not a DS18x20 family device.");
      return;
  }

  ds.reset();
  ds.select(addr);
  ds.write(0x44, 1);        // start conversion, with parasite power on at the end
 
  delay(1000);     // maybe 750ms is enough, maybe not
  // we might do a ds.depower() here, but the reset will take care of it.
 
  present = ds.reset();
  ds.select(addr);   
  ds.write(0xBE);         // Read Scratchpad

  Serial.print("  Data = ");
  Serial.print(present, HEX);
  Serial.print(" ");
  for ( i = 0; i < 9; i++) {           // we need 9 bytes
    data[i] = ds.read();
    Serial.print(data[i], HEX);
    Serial.print(" ");
  }
  Serial.print(" CRC=");
  Serial.print(OneWire::crc8(data, 8), HEX);
  Serial.println();

  // Convert the data to actual temperature
  // because the result is a 16 bit signed integer, it should
  // be stored to an "int16_t" type, which is always 16 bits
  // even when compiled on a 32 bit processor.
  int16_t raw = (data[1] << 8) | data[0];
  if (type_s) {
    raw = raw << 3; // 9 bit resolution default
    if (data[7] == 0x10) {
      // "count remain" gives full 12 bit resolution
      raw = (raw & 0xFFF0) + 12 - data[6];
    }
  } else {
    byte cfg = (data[4] & 0x60);
    // at lower res, the low bits are undefined, so let's zero them
    if (cfg == 0x00) raw = raw & ~7;  // 9 bit resolution, 93.75 ms
    else if (cfg == 0x20) raw = raw & ~3; // 10 bit res, 187.5 ms
    else if (cfg == 0x40) raw = raw & ~1; // 11 bit res, 375 ms
    //// default is 12 bit resolution, 750 ms conversion time
  }
  celsius = (float)raw / 16.0;
  fahrenheit = celsius * 1.8 + 32.0;
  Serial.print("  Temperature = ");
  Serial.print(celsius);
  Serial.print(" Celsius, ");
  Serial.print(fahrenheit);
  Serial.println(" Fahrenheit");
}

Should I post OneWire.h as well?

The only thing I changed from the example is the pin... And the baud rate...

- Thu Mar 03, 2016 4:34 pm #42365 Just for completeness, here is the output from the console:

Code: Select allROM = 28 E4 8C 5D 0 0 0 44
  Chip = DS18B20
  Data = 1 90 5 FF FF 7F FF 10 10 1  CRC=1
  Temperature = 89.00 Celsius, 192.20 Fahrenheit
ROM = 28 23 B4 5D 0 0 0 E4
  Chip = DS18B20
  Data = 1 84 5 55 55 7F FF C 10 FC  CRC=FC
  Temperature = 88.25 Celsius, 190.85 Fahrenheit
No more addresses.

ROM = 28 E4 8C 5D 0 0 0 44
  Chip = DS18B20
  Data = 1 9E 5 FF FF 7F FF 2 10 C5  CRC=C5
  Temperature = 89.87 Celsius, 193.77 Fahrenheit
ROM = 28 23 B4 5D 0 0 0 E4
  Chip = DS18B20
  Data = 1 8F 5 55 55 7F FF 1 10 9A  CRC=9A
  Temperature = 88.94 Celsius, 192.09 Fahrenheit
No more addresses.

ROM = 28 E4 8C 5D 0 0 0 44
  Chip = DS18B20
  Data = 1 A0 5 FF FF 7F FF 10 10 FD  CRC=FD
  Temperature = 90.00 Celsius, 194.00 Fahrenheit
ROM = 28 23 B4 5D 0 0 0 E4
  Chip = DS18B20
  Data = 1 8E 5 55 55 7F FF 2 10 8C  CRC=8C
  Temperature = 88.87 Celsius, 191.98 Fahrenheit
No more addresses.


Thanks for your help again, I'm completely out of ideas what causes the problem.