ESP8266 Community Forum

- Sun Mar 11, 2018 4:26 pm #74534 Banged my head against this problem for a good 6+ hours yesterday. Hoping I could get a pair of more knowledgeable eyes on this too

I'm trying to read data from a waterproof DS18B20 temperature sensor with a Wemos D1 Mini Lite. Here's a picture of my setup https://imgur.com/eHXnFes.

I'm using the Arduino IDE with "WEMOS D1 mini Lite" selected for my board. I followed the git installation instructions on this page https://wiki.wemos.cc/tutorials:get_sta ... in_arduino. I tried reading from the sensor and I always get the value -127. I read a suggestion to test using the DS18x20_Temperature sample script, so I did that and it prints "No more addresses." to Serial in a loop. It looks like OneWire.search(addr) is unable to find anything. Here's the sample code I'm running:

Code: Select all#include <OneWire.h>

// OneWire DS18S20, DS18B20, DS1822 Temperature Example
//
// http://www.pjrc.com/teensy/td_libs_OneWire.html
//
// The DallasTemperature library can do all this work for you!
// http://milesburton.com/Dallas_Temperature_Control_Library

OneWire  ds(D2);  // on pin 4 (a 4.7K resistor is necessary)

void setup(void) {
  Serial.begin(9600);
}

void loop(void) {
  byte i;
  byte present = 0;
  byte type_s;
  byte data[12];
  byte addr[8];
  float celsius, fahrenheit;
 
  if ( !ds.search(addr)) {
    Serial.println("No more addresses.");
    Serial.println();
    ds.reset_search();
    delay(250);
   
    return;
  }
 
  Serial.print("ROM =");
  for( i = 0; i < 8; i++) {
    Serial.write(' ');
    Serial.print(addr[i], HEX);
  }

  if (OneWire::crc8(addr, 7) != addr[7]) {
      Serial.println("CRC is not valid!");
      return;
  }
  Serial.println();
 
  // the first ROM byte indicates which chip
  switch (addr[0]) {
    case 0x10:
      Serial.println("  Chip = DS18S20");  // or old DS1820
      type_s = 1;
      break;
    case 0x28:
      Serial.println("  Chip = DS18B20");
      type_s = 0;
      break;
    case 0x22:
      Serial.println("  Chip = DS1822");
      type_s = 0;
      break;
    default:
      Serial.println("Device is not a DS18x20 family device.");
      return;
  }

  ds.reset();
  ds.select(addr);
  ds.write(0x44, 1);        // start conversion, with parasite power on at the end
 
  delay(1000);     // maybe 750ms is enough, maybe not
  // we might do a ds.depower() here, but the reset will take care of it.
 
  present = ds.reset();
  ds.select(addr);   
  ds.write(0xBE);         // Read Scratchpad

  Serial.print("  Data = ");
  Serial.print(present, HEX);
  Serial.print(" ");
  for ( i = 0; i < 9; i++) {           // we need 9 bytes
    data[i] = ds.read();
    Serial.print(data[i], HEX);
    Serial.print(" ");
  }
  Serial.print(" CRC=");
  Serial.print(OneWire::crc8(data, 8), HEX);
  Serial.println();

  // Convert the data to actual temperature
  // because the result is a 16 bit signed integer, it should
  // be stored to an "int16_t" type, which is always 16 bits
  // even when compiled on a 32 bit processor.
  int16_t raw = (data[1] << 8) | data[0];
  if (type_s) {
    raw = raw << 3; // 9 bit resolution default
    if (data[7] == 0x10) {
      // "count remain" gives full 12 bit resolution
      raw = (raw & 0xFFF0) + 12 - data[6];
    }
  } else {
    byte cfg = (data[4] & 0x60);
    // at lower res, the low bits are undefined, so let's zero them
    if (cfg == 0x00) raw = raw & ~7;  // 9 bit resolution, 93.75 ms
    else if (cfg == 0x20) raw = raw & ~3; // 10 bit res, 187.5 ms
    else if (cfg == 0x40) raw = raw & ~1; // 11 bit res, 375 ms
    //// default is 12 bit resolution, 750 ms conversion time
  }
  celsius = (float)raw / 16.0;
  fahrenheit = celsius * 1.8 + 32.0;
  Serial.print("  Temperature = ");
  Serial.print(celsius);
  Serial.print(" Celsius, ");
  Serial.print(fahrenheit);
  Serial.println(" Fahrenheit");
}


I was able to upload the example "Blink" program to the D1 mini Lite, and I was able to read good temperature values from the same sensor using a Raspberry Pi (using red/blue/yellow as vcc/gnd/data), so I don't either piece of equipment is broken.

I also read a suggestion to use a 2.2K pullup resistor instead of the standard 4.7K, but that didn't help either.
I've also tried using pins D1 and D4 instead of D2 to no avail. For what it's worth, a digitalRead of D2 always returns 0 for me.

I'm so stumped. I might just buy a normal Wemos D1 mini instead of the lite to see if that fixes it somehow. Any advice/comments would be greatly appreciated.

- Fri Mar 16, 2018 6:27 pm #74648 Update: I bought an Adafruit Feather HUZZAH ESP8266 and am still running into the same problem. Very confusing.

- Fri Mar 16, 2018 9:55 pm #74650 Have you used an Ohm meter and checked to see if you have a short between data and ground? Maybe the sensor is bad. If it measures okay then have you tested the sensor on a non-ESP8266 board, like a basic Arduino?

When you were getting a low from reading the port pin, did you measure the voltage with a meter?

Looking at your picture again, I don't think you should be using 5 volts on the pull-up resistor. The ESP8266 is not supposed to be 5 volt tolerant on it's input pins.

I tried the program on my setup and it worked.

- Sat Mar 17, 2018 4:38 am #74655 esp8266 does not like 5V. try powering the sensor from 3.3V.
alternatively try one the dedicated dallas libraries https://goo.gl/89XZV7